This is the mail archive of the binutils@sources.redhat.com mailing list for the binutils project.


Index Nav: [Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav: [Date Prev] [Date Next] [Thread Prev] [Thread Next]
Other format: [Raw text]

[PATCH] Update bfd to autoconf 2.5x, take 2


This performs the minimal update to autoconf 2.59 for bfd; another important
step in updating the whole of src to 2.59.  This is the revised version,
which actually handles bfd install correctly.

Built on i686-pc-linux-gnu with no serious differences in generated files.

There are most definitely further cleanups which I might make later.

OK to commit?

	* acinclude.m4: Require AC_CANONICAL_TARGET, not AC_CANONICAL_SYSTEM.
	Include ../config/acx.m4 and use ACX_NONCANONICAL_* where appropriate;
	replace uses of *_alias with *_noncanonical.
	* aclocal.m4: Rebuild with aclocal 1.4p6.
	* Makefile.in: Rebuild with automake 1.4p6.
	* doc/Makefile.in: Rebuild with automake 1.4p6.
	* configure.in: Autoupdate with autoupdate 2.59.
	* config.in: Regenerate with autoheader 2.59.
	* configure: Regnerate with autoconf 2.59.

Index: configure.in
===================================================================
RCS file: /cvs/src/src/bfd/configure.in,v
retrieving revision 1.158
diff -u -r1.158 configure.in
--- configure.in	27 Jul 2004 22:30:23 -0000	1.158
+++ configure.in	28 Aug 2004 09:50:55 -0000
@@ -1,10 +1,11 @@
 dnl Process this file with autoconf to produce a configure script.
 dnl
 
-AC_PREREQ(2.13)
-AC_INIT(libbfd.c)
+AC_PREREQ(2.59)
+AC_INIT
+AC_CONFIG_SRCDIR([libbfd.c])
 
-AC_CANONICAL_SYSTEM
+AC_CANONICAL_TARGET
 AC_ISC_POSIX
 
 AM_INIT_AUTOMAKE(bfd, 2.15.91)
@@ -30,7 +31,7 @@
 AC_ARG_ENABLE(targets,
 [  --enable-targets        alternative target configurations],
 [case "${enableval}" in
-  yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
+  yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
             ;;
   no)       enable_targets= ;;
   *)        enable_targets=$enableval ;;
@@ -106,9 +107,7 @@
 
 AC_MSG_CHECKING([for long long])
 AC_CACHE_VAL(bfd_cv_has_long_long,
-[AC_TRY_COMPILE(,
-[unsigned long long ll = 18446744073709551615ULL;],
-bfd_cv_has_long_long=yes, bfd_cv_has_long_long=no)])
+[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
 AC_MSG_RESULT($bfd_cv_has_long_long)
 if test $bfd_cv_has_long_long = yes; then
   BFD_HOST_LONG_LONG=1
@@ -343,9 +342,7 @@
 	# Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 	# have c_impl as a member of struct core_dumpx
 	AC_MSG_CHECKING([for c_impl in struct core_dumpx])
-	AC_TRY_COMPILE([#include <core.h>],
-	  [struct core_dumpx c; c.c_impl = 0;],
-	  [AC_DEFINE(HAVE_ST_C_IMPL, 1,
+	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 	    [Define if struct core_dumpx has member c_impl])
 	  AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 	;;
@@ -886,7 +883,7 @@
 		    AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 		    AC_MSG_RESULT(no))
        if test $bad_64bit_gcc = yes ; then
-	 AC_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
+	 AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
        fi
     fi
     ;;
@@ -942,6 +939,7 @@
 esac
 
 rm -f doc/config.status
-AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in,
-[sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile])
+AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
+AC_CONFIG_COMMANDS([default],[[sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile]],[[]])
+AC_OUTPUT
 
Index: acinclude.m4
===================================================================
RCS file: /cvs/src/src/bfd/acinclude.m4,v
retrieving revision 1.10
diff -u -r1.10 acinclude.m4
--- acinclude.m4	14 Jan 2004 13:41:36 -0000	1.10
+++ acinclude.m4	28 Aug 2004 09:50:55 -0000
@@ -1,8 +1,9 @@
 sinclude(../config/accross.m4)
+sinclude(../config/acx.m4)
 
 dnl See whether we need to use fopen-bin.h rather than fopen-same.h.
 AC_DEFUN([BFD_BINARY_FOPEN],
-[AC_REQUIRE([AC_CANONICAL_SYSTEM])
+[AC_REQUIRE([AC_CANONICAL_TARGET])
 case "${host}" in
 changequote(,)dnl
 *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
@@ -138,12 +139,15 @@
       fi)
   AC_MSG_RESULT($install_libbfd_p)
   AM_CONDITIONAL(INSTALL_LIBBFD, test $install_libbfd_p = yes)
+  # Need _noncanonical variables for this.
+  ACX_HOST_NONCANONICAL
+  ACX_TARGET_NONCANONICAL
   # libbfd.a is a host library containing target dependent code
   bfdlibdir='$(libdir)'
   bfdincludedir='$(includedir)'
   if test "${host}" != "${target}"; then
-    bfdlibdir='$(exec_prefix)/$(host_alias)/$(target_alias)/lib'
-    bfdincludedir='$(exec_prefix)/$(host_alias)/$(target_alias)/include'
+    bfdlibdir='$(exec_prefix)/$(host_noncanonical)/$(target_noncanonical)/lib'
+    bfdincludedir='$(exec_prefix)/$(host_noncanonical)/$(target_noncanonical)/include'
   fi
   AC_SUBST(bfdlibdir)
   AC_SUBST(bfdincludedir)

-- 
This space intentionally left blank.


Index Nav: [Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav: [Date Prev] [Date Next] [Thread Prev] [Thread Next]