This is the mail archive of the
xsl-list@mulberrytech.com
mailing list .
Re: translate (string, ''' , '''' )
- To: Samuzeau Pascal <samuzeau at sunaimed dot med dot univ-rennes1 dot fr>
- Subject: Re: [xsl] translate (string, ''' , '''' )
- From: Jeni Tennison <mail at jenitennison dot com>
- Date: Mon, 5 Mar 2001 18:18:09 +0000
- CC: XML <xsl-list at lists dot mulberrytech dot com>
- Organization: Jeni Tennison Consulting Ltd
- References: <3AA3A091.E7DB6FF5@sunaimed.univ-rennes1.fr>
- Reply-To: xsl-list at lists dot mulberrytech dot com
Hi Pascal,
> I Have a XSL as :
>
> <xsl:variable name="N" >
> <xsl:value-of select="translate(/Legende, ''', '''' ) " />
> </xsl:variable>
>
> I want to translate my " isn't " as " isn''t"
The translate() function only works for translating single characters
into other single characters - you can't use it to replace a single
character with more than one character as you're doing here.
Instead, you have to use a recursive named template. If it finds an
apostrophe in the string, it gives (a) the string before the
apostrophe (b) two apostrophes and (c) whatever you get if you call
the template on the string after the apostrophe. If it doesn't find
an apostrophe in the string, it just gives you the string:
<xsl:template name="escape-apos">
<xsl:param name="string" />
<xsl:choose>
<xsl:when test='contains($string, "'")'>
<xsl:value-of select='substring-before($string, "'")' />
<xsl:text>''</xsl:text>
<xsl:call-template name="escape-apos">
<xsl:with-param name="string"
select='substring-after($string, "'")' />
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$string" />
</xsl:otherwise>
</xsl:choose>
</xsl:template>
I hope that helps,
Jeni
---
Jeni Tennison
http://www.jenitennison.com/
XSL-List info and archive: http://www.mulberrytech.com/xsl/xsl-list