This is the mail archive of the
xsl-list@mulberrytech.com
mailing list .
Re: How do you get the most recent element?
- To: "Tom Gilbert" <tom dot gilbert at cartanova dot com>
- Subject: Re: [xsl] How do you get the most recent element?
- From: Jeni Tennison <mail at jenitennison dot com>
- Date: Tue, 13 Feb 2001 09:39:10 +0000
- CC: XSL-List at lists dot mulberrytech dot com
- Organization: Jeni Tennison Consulting Ltd
- References: <NEBBKANNKPLAJDMOBJFEIEKOCAAA.tom.gilbert@cartanova.com>
- Reply-To: xsl-list at lists dot mulberrytech dot com
Hi Tom,
> I need to display the most recent "note". I did something like shown
> below. I'm concerned that the match will go through all the sorted
> notes even though I only want the most recent. Thought there might
> be a more elegant solution out there.
Another solution is to use just an XPath to get what you want. The
most recent note is the one such that no other notes have a date
greater than this one. You can express this as:
note[not(../note/date > date)][1]
And thus just use:
<xsl:value-of select="note[not(../note/date > date)][1]/text" />
to get the text of the most recent note rather than applying templates
or sorting or recursing or whatever.
However, this is probably an even worse solution for large data sets
than the 'sort and pick first' solution. A good recursive solution
would be:
<!-- apply templates to only the first note -->
<xsl:apply-templates select="note[1]" />
...
<xsl:template match="note">
<!-- find the next note that's more recent than this one -->
<xsl:variable name="next"
select="following-sibling::note
[date > current()/date][1]" />
<xsl:choose>
<xsl:when test="$next">
<!-- if there is a more recent note, apply templates to it
-->
<xsl:apply-templates select="$next" />
</xsl:when>
<xsl:otherwise>
<!-- otherwise give the value of the text of this one -->
<xsl:value-of select="text" />
</xsl:otherwise>
</xsl:choose>
</xsl:template>
I hope that helps,
Jeni
---
Jeni Tennison
http://www.jenitennison.com/
XSL-List info and archive: http://www.mulberrytech.com/xsl/xsl-list