This is the mail archive of the libc-alpha@sources.redhat.com mailing list for the glibc project.


Index Nav: [Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav: [Date Prev] [Date Next] [Thread Prev] [Thread Next]
Other format: [Raw text]

[PATCH] PPC32 enable Altivec for setjmp/longjmp part 2 of 5


This revised patch fixes a version naming bug for the old __sigsetjmp for 32-bit.
2004-02-04  Steven Munroe  <sjmunroe@us.ibm.com>

	* sysdeps/powerpc/powerpc32/__longjmp-common.S: New File
	* sysdeps/powerpc/powerpc32/__longjmp.S(__vmx__longjmp): Add VMX reg 
	support and define as default version of __longjmp.
	[SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4)]
	(__novmx__longjmp): Original version of __longjmp.
	* sysdeps/powerpc/powerpc32/bsd-_setjmp.S(__vmx_setjmp): Branch to 
	__vmx__sigsetjmp and define as default version of _setjmp.
	[SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4)]
	(__novmx_setjmp): Original version of _setjmp.
	* sysdeps/powerpc/powerpc32/bsd-setjmp.S(__vmxsetjmp): Branch to 
	__vmx__sigsetjmp and define as default version of setjmp.
	[SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4)]
	(__novmxsetjmp): Original version of setjmp.
	* sysdeps/powerpc/powerpc32/fpu/__longjmp-common.S: New file.
	* sysdeps/powerpc/powerpc32/fpu/__longjmp.S(__vmx__longjmp): Add VMX
	reg support and define as default version of __longjmp.
	[SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4)]
	(__novmx__longjmp): Original version of __longjmp.
	* sysdeps/powerpc/powerpc32/fpu/setjmp-common.S: New file.
	* sysdeps/powerpc/powerpc32/fpu/setjmp.S(__vmx__sigsetjmp): Add VMX
	reg support and define as default version of __sigsetjmp.
	[SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4)]
	(__novmx__sigsetjmp): Original version of __sigsetjmp.
	* sysdeps/powerpc/powerpc32/setjmp-common.S: New file.
	* sysdeps/powerpc/powerpc32/setjmp.S(__vmx__sigsetjmp): Add VMX
	reg support and define as default version of __sigsetjmp.
	[SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4)]
	(__novmx__sigsetjmp): Original version of __sigsetjmp.

diff -urN libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/__longjmp-common.S libc23/sysdeps/powerpc/powerpc32/__longjmp-common.S
--- libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/__longjmp-common.S	Wed Dec 31 17:00:00 1969
+++ libc23/sysdeps/powerpc/powerpc32/__longjmp-common.S	Fri Jan 30 14:31:29 2004
@@ -0,0 +1,59 @@
+/* longjmp for PowerPC.
+   Copyright (C) 1995, 1996, 1997, 1999, 2000, 2001, 2003 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+#define _ASM
+#define _SETJMP_H
+#ifdef __NO_VMX__
+#include <novmxsetjmp.h>
+#else
+#include <bits/setjmp.h>
+#endif
+#include <bp-sym.h>
+#include <bp-asm.h>
+
+ENTRY (BP_SYM (__longjmp))
+	CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
+
+	lwz r1,(JB_GPR1*4)(r3)
+	lwz r0,(JB_LR*4)(r3)
+	lwz r14,((JB_GPRS+0)*4)(r3)
+	lwz r15,((JB_GPRS+1)*4)(r3)
+	lwz r16,((JB_GPRS+2)*4)(r3)
+	lwz r17,((JB_GPRS+3)*4)(r3)
+	lwz r18,((JB_GPRS+4)*4)(r3)
+	lwz r19,((JB_GPRS+5)*4)(r3)
+	lwz r20,((JB_GPRS+6)*4)(r3)
+	mtlr r0
+	lwz r21,((JB_GPRS+7)*4)(r3)
+	lwz r22,((JB_GPRS+8)*4)(r3)
+	lwz r0,(JB_CR*4)(r3)
+	lwz r23,((JB_GPRS+9)*4)(r3)
+	lwz r24,((JB_GPRS+10)*4)(r3)
+	lwz r25,((JB_GPRS+11)*4)(r3)
+	mtcrf 0xFF,r0
+	lwz r26,((JB_GPRS+12)*4)(r3)
+	lwz r27,((JB_GPRS+13)*4)(r3)
+	lwz r28,((JB_GPRS+14)*4)(r3)
+	lwz r29,((JB_GPRS+15)*4)(r3)
+	lwz r30,((JB_GPRS+16)*4)(r3)
+	lwz r31,((JB_GPRS+17)*4)(r3)
+	mr r3,r4
+	blr
+END (BP_SYM (__longjmp))
diff -urN libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/__longjmp.S libc23/sysdeps/powerpc/powerpc32/__longjmp.S
--- libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/__longjmp.S	2003-02-17 14:46:03.000000000 -0600
+++ libc23/sysdeps/powerpc/powerpc32/__longjmp.S	2004-01-29 13:12:25.000000000 -0600
@@ -1,5 +1,5 @@
-/* longjmp for PowerPC.
-   Copyright (C) 1995, 1996, 1997, 1999, 2000, 2001 Free Software Foundation, Inc.
+/* AltiVec/VMX (new) version of __longjmp for PowerPC.
+   Copyright (C)  1995, 1996, 1997, 1999, 2000, 2003, 2004 Free Software Foundation, Inc.
    This file is part of the GNU C Library.
 
    The GNU C Library is free software; you can redistribute it and/or
@@ -17,39 +17,18 @@
    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
    02111-1307 USA.  */
 
-#include <sysdep.h>
-#define _ASM
-#define _SETJMP_H
-#include <bits/setjmp.h>
-#include <bp-sym.h>
-#include <bp-asm.h>
-
-ENTRY (BP_SYM (__longjmp))
-	CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
-
-	lwz r1,(JB_GPR1*4)(r3)
-	lwz r0,(JB_LR*4)(r3)
-	lwz r14,((JB_GPRS+0)*4)(r3)
-	lwz r15,((JB_GPRS+1)*4)(r3)
-	lwz r16,((JB_GPRS+2)*4)(r3)
-	lwz r17,((JB_GPRS+3)*4)(r3)
-	lwz r18,((JB_GPRS+4)*4)(r3)
-	lwz r19,((JB_GPRS+5)*4)(r3)
-	lwz r20,((JB_GPRS+6)*4)(r3)
-	mtlr r0
-	lwz r21,((JB_GPRS+7)*4)(r3)
-	lwz r22,((JB_GPRS+8)*4)(r3)
-	lwz r0,(JB_CR*4)(r3)
-	lwz r23,((JB_GPRS+9)*4)(r3)
-	lwz r24,((JB_GPRS+10)*4)(r3)
-	lwz r25,((JB_GPRS+11)*4)(r3)
-	mtcrf 0xFF,r0
-	lwz r26,((JB_GPRS+12)*4)(r3)
-	lwz r27,((JB_GPRS+13)*4)(r3)
-	lwz r28,((JB_GPRS+14)*4)(r3)
-	lwz r29,((JB_GPRS+15)*4)(r3)
-	lwz r30,((JB_GPRS+16)*4)(r3)
-	lwz r31,((JB_GPRS+17)*4)(r3)
-	mr r3,r4
-	blr
-END (BP_SYM (__longjmp))
+#include <libc-symbols.h>
+#include <shlib-compat.h>
+
+default_symbol_version (__vmx__longjmp,__longjmp,GLIBC_2.3.4);
+#define __longjmp  __vmx__longjmp
+#include "__longjmp-common.S"
+
+#if defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4)
+#define __NO_VMX__
+symbol_version (__novmx__longjmp,__longjmp,GLIBC_2.0);
+#undef __longjmp
+#define __longjmp  __novmx__longjmp
+#include "__longjmp-common.S"
+#endif
+
diff -urN libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/bsd-_setjmp.S libc23/sysdeps/powerpc/powerpc32/bsd-_setjmp.S
--- libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/bsd-_setjmp.S	2002-12-31 14:37:23.000000000 -0600
+++ libc23/sysdeps/powerpc/powerpc32/bsd-_setjmp.S	2004-01-29 13:12:25.000000000 -0600
@@ -1,5 +1,5 @@
-/* BSD `_setjmp' entry point to `sigsetjmp (..., 0)'.  PowerPC version.
-   Copyright (C) 1994, 1997, 1999, 2000, 2002 Free Software Foundation, Inc.
+/* BSD `_setjmp' entry point to `sigsetjmp (..., 0)'.  PowerPC32/64 version.
+   Copyright (C) 1994, 1997, 1999, 2000, 2002, 2003 Free Software Foundation, Inc.
    This file is part of the GNU C Library.
 
    The GNU C Library is free software; you can redistribute it and/or
@@ -16,16 +16,32 @@
    License along with the GNU C Library; if not, write to the Free
    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
    02111-1307 USA.  */
-
-/* This just does a tail-call to `__sigsetjmp (ARG, 0)'.
-   We cannot do it in C because it must be a tail-call, so frame-unwinding
-   in setjmp doesn't clobber the state restored by longjmp.  */
-
+#include <shlib-compat.h>
+#include <libc-symbols.h>
 #include <sysdep.h>
 #include <bp-sym.h>
+	
+#if defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4)	
+symbol_version (__novmx_setjmp,_setjmp,GLIBC_2.0);
+
+ENTRY (BP_SYM (__novmx_setjmp))
+	li r4,0			/* Set second argument to 0.  */
+	b JUMPTARGET(BP_SYM (__novmx__sigsetjmp))
+END (BP_SYM (__novmx_setjmp))
+libc_hidden_def (__novmx_setjmp)
+#endif /* defined SHARED  && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4) */
+
+default_symbol_version (__vmx_setjmp,_setjmp,GLIBC_2.3.4)
+/* __GI__setjmp prototype is needed for ntpl i.e. _setjmp is defined
+   as a libc_hidden_proto & is used in sysdeps/generic/libc-start.c
+   if HAVE_CLEANUP_JMP_BUF is defined */
+ENTRY (BP_SYM (__GI__setjmp))
+	li r4,0			/* Set second argument to 0.  */
+	b JUMPTARGET(BP_SYM (__vmx__sigsetjmp))
+END (BP_SYM (__GI__setjmp))
 
-ENTRY (BP_SYM (_setjmp))
+ENTRY (BP_SYM (__vmx_setjmp))
 	li r4,0			/* Set second argument to 0.  */
-	b JUMPTARGET(BP_SYM (__sigsetjmp))
-END (BP_SYM (_setjmp))
-libc_hidden_def (_setjmp)
+	b JUMPTARGET(BP_SYM (__vmx__sigsetjmp))
+END (BP_SYM (__vmx_setjmp))
+libc_hidden_def (__vmx_setjmp)
diff -urN libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/bsd-setjmp.S libc23/sysdeps/powerpc/powerpc32/bsd-setjmp.S
--- libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/bsd-setjmp.S	2002-09-05 03:23:27.000000000 -0500
+++ libc23/sysdeps/powerpc/powerpc32/bsd-setjmp.S	2004-01-29 13:12:25.000000000 -0600
@@ -1,5 +1,5 @@
-/* BSD `setjmp' entry point to `sigsetjmp (..., 1)'.  PowerPC version.
-   Copyright (C) 1994, 1997, 1999, 2000 Free Software Foundation, Inc.
+/* BSD `setjmp' entry point to `sigsetjmp (..., 1)'.  PowerPC32/64 version.
+   Copyright (C) 1994, 1997, 1999, 2000, 2003 Free Software Foundation, Inc.
    This file is part of the GNU C Library.
 
    The GNU C Library is free software; you can redistribute it and/or
@@ -16,17 +16,43 @@
    License along with the GNU C Library; if not, write to the Free
    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
    02111-1307 USA.  */
-
-/* This just does a tail-call to `__sigsetjmp (ARG, 1)'.
-   We cannot do it in C because it must be a tail-call, so frame-unwinding
-   in setjmp doesn't clobber the state restored by longjmp.  */
-
+#include <shlib-compat.h>
+#include <libc-symbols.h>
 #include <sysdep.h>
 #include <bp-sym.h>
 
-ENTRY (BP_SYM (__setjmp))
+#if defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4)
+
+
+/* We need 2 copies of identicatal code for the  setjmp's as gas complains 
+  erronously about having multiple versions of setjmp this eliminates the
+  need for the strong alias of __setjmp to setjmp which 
+  does not support versioning i.e. another gas unimplemented feature. */
+symbol_version (__novmx__setjmp,__setjmp,GLIBC_2.0)
+symbol_version (__novmxsetjmp,setjmp,GLIBC_2.0)
+		
+ENTRY (BP_SYM (__novmxsetjmp))
+	li r4,1			/* Set second argument to 1.  */
+	b JUMPTARGET (BP_SYM (__novmx__sigsetjmp))
+END (BP_SYM (__novmxsetjmp))
+
+ENTRY (BP_SYM (__novmx__setjmp))
+	li r4,1			/* Set second argument to 1.  */
+	b JUMPTARGET (BP_SYM (__novmx__sigsetjmp))
+END (BP_SYM (__novmx__setjmp))
+#endif  /* defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4) ) */
+
+default_symbol_version (__vmx__setjmp,__setjmp,GLIBC_2.3.4)
+default_symbol_version (__vmxsetjmp,setjmp,GLIBC_2.3.4)
+		
+ENTRY (BP_SYM (__vmxsetjmp))
+	li r4,1			/* Set second argument to 1.  */
+	b JUMPTARGET (BP_SYM (__vmx__sigsetjmp))
+END (BP_SYM (__vmxsetjmp))
+
+ENTRY (BP_SYM (__vmx__setjmp))
 	li r4,1			/* Set second argument to 1.  */
-	b JUMPTARGET (BP_SYM (__sigsetjmp))
-END (BP_SYM (__setjmp))
+	b JUMPTARGET (BP_SYM (__vmx__sigsetjmp))
+END (BP_SYM (__vmx__setjmp))
 
-strong_alias (__setjmp, setjmp)
+	
diff -urN libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/fpu/__longjmp-common.S libc23/sysdeps/powerpc/powerpc32/fpu/__longjmp-common.S
--- libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/fpu/__longjmp-common.S	Wed Dec 31 17:00:00 1969
+++ libc23/sysdeps/powerpc/powerpc32/fpu/__longjmp-common.S	Fri Jan 30 14:31:54 2004
@@ -0,0 +1,151 @@
+/* longjmp for PowerPC.
+   Copyright (C) 1995-99, 2000, 2003, 2004 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+   AltiVec/VMX support contributed by Denis Joseph Barrow (dj@de.ibm.com).
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+#define _ASM
+#define _SETJMP_H
+#ifdef __NO_VMX__
+#include <novmxsetjmp.h>
+#else
+#include <bits/setjmp.h>
+#endif
+#include <bp-sym.h>
+#include <bp-asm.h>
+
+ENTRY (BP_SYM (__longjmp))
+	CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
+#ifndef __NO_VMX__
+#ifdef PIC
+	mflr    r6
+	bl      _GLOBAL_OFFSET_TABLE_@local-4
+	mflr    r5
+#ifdef SHARED
+	lwz     r5,_rtld_global@got(r5)
+	mtlr    r6
+	lwz     r5,RTLD_GLOBAL_DL_HWCAP_OFFSET(r5)	
+#else
+	lwz     r5,_rtld_global@got(r5)
+	mtlr    r6
+	lwz     r5,0(r5)
+#endif
+#else
+	lis	r5,_dl_hwcap@ha
+	lwz     r5,_dl_hwcap@l(r5)
+#endif
+	andis.	r5,r5,(PPC_FEATURE_HAS_ALTIVEC >> 16)
+	beq	no_vmx
+	la	r5,((JB_VRS)*4)(3)
+	andi.	r6,r5,0xf
+	lwz	r0,((JB_VRSAVE)*4)(3)
+	mtspr	VRSAVE,r0
+	beq+	aligned_restore_vmx
+	addi    r6,r5,16
+	lvsl	v0,0,r5
+	lvx	v1,0,r5
+	addi    r5,r5,32
+	lvx	v21,0,r6
+	vperm   v20,v1,v21,v0	
+#define load_misaligned_vmx_lo_loaded(loadvr,lovr,shiftvr,loadgpr,addgpr) \
+	addi    addgpr,addgpr,32; \
+	lvx	lovr,0,loadgpr; \
+	vperm   loadvr,loadvr,lovr,shiftvr; 
+	load_misaligned_vmx_lo_loaded(v21,v22,v0,r5,r6)
+	load_misaligned_vmx_lo_loaded(v22,v23,v0,r6,r5)
+	load_misaligned_vmx_lo_loaded(v23,v24,v0,r5,r6)
+	load_misaligned_vmx_lo_loaded(v24,v25,v0,r6,r5)
+	load_misaligned_vmx_lo_loaded(v25,v26,v0,r5,r6)
+	load_misaligned_vmx_lo_loaded(v26,v27,v0,r6,r5)
+	load_misaligned_vmx_lo_loaded(v27,v28,v0,r5,r6)
+	load_misaligned_vmx_lo_loaded(v28,v29,v0,r6,r5)
+	load_misaligned_vmx_lo_loaded(v29,v30,v0,r5,r6)
+	load_misaligned_vmx_lo_loaded(v30,v31,v0,r6,r5)
+	lvx	v1,0,r5
+	vperm   v31,v31,v1,v0
+	b       no_vmx
+aligned_restore_vmx:
+	addi	r6,r5,16
+	lvx	v20,0,r5
+	addi	r5,r5,32
+	lvx	v21,0,r6
+	addi	r6,r6,32
+	lvx	v22,0,r5
+	addi	r5,r5,32
+	lvx	v23,0,r6
+	addi	r6,r6,32
+	lvx	v24,0,r5
+	addi	r5,r5,32
+	lvx	v25,0,r6
+	addi	r6,r6,32
+	lvx	v26,0,r5
+	addi	r5,r5,32
+	lvx	v27,0,r6
+	addi	r6,r6,32
+	lvx	v28,0,r5
+	addi	r5,r5,32
+	lvx	v29,0,r6
+	addi	r6,r6,32
+	lvx	v30,0,r5
+	lvx	v31,0,r6
+no_vmx:		
+#endif
+	lwz r1,(JB_GPR1*4)(r3)
+	lwz r0,(JB_LR*4)(r3)
+	lwz r14,((JB_GPRS+0)*4)(r3)
+	lfd fp14,((JB_FPRS+0*2)*4)(r3)
+	lwz r15,((JB_GPRS+1)*4)(r3)
+	lfd fp15,((JB_FPRS+1*2)*4)(r3)
+	lwz r16,((JB_GPRS+2)*4)(r3)
+	lfd fp16,((JB_FPRS+2*2)*4)(r3)
+	lwz r17,((JB_GPRS+3)*4)(r3)
+	lfd fp17,((JB_FPRS+3*2)*4)(r3)
+	lwz r18,((JB_GPRS+4)*4)(r3)
+	lfd fp18,((JB_FPRS+4*2)*4)(r3)
+	lwz r19,((JB_GPRS+5)*4)(r3)
+	lfd fp19,((JB_FPRS+5*2)*4)(r3)
+	lwz r20,((JB_GPRS+6)*4)(r3)
+	lfd fp20,((JB_FPRS+6*2)*4)(r3)
+	mtlr r0
+	lwz r21,((JB_GPRS+7)*4)(r3)
+	lfd fp21,((JB_FPRS+7*2)*4)(r3)
+	lwz r22,((JB_GPRS+8)*4)(r3)
+	lfd fp22,((JB_FPRS+8*2)*4)(r3)
+	lwz r0,(JB_CR*4)(r3)
+	lwz r23,((JB_GPRS+9)*4)(r3)
+	lfd fp23,((JB_FPRS+9*2)*4)(r3)
+	lwz r24,((JB_GPRS+10)*4)(r3)
+	lfd fp24,((JB_FPRS+10*2)*4)(r3)
+	lwz r25,((JB_GPRS+11)*4)(r3)
+	lfd fp25,((JB_FPRS+11*2)*4)(r3)
+	mtcrf 0xFF,r0
+	lwz r26,((JB_GPRS+12)*4)(r3)
+	lfd fp26,((JB_FPRS+12*2)*4)(r3)
+	lwz r27,((JB_GPRS+13)*4)(r3)
+	lfd fp27,((JB_FPRS+13*2)*4)(r3)
+	lwz r28,((JB_GPRS+14)*4)(r3)
+	lfd fp28,((JB_FPRS+14*2)*4)(r3)
+	lwz r29,((JB_GPRS+15)*4)(r3)
+	lfd fp29,((JB_FPRS+15*2)*4)(r3)
+	lwz r30,((JB_GPRS+16)*4)(r3)
+	lfd fp30,((JB_FPRS+16*2)*4)(r3)
+	lwz r31,((JB_GPRS+17)*4)(r3)
+	lfd fp31,((JB_FPRS+17*2)*4)(r3)
+	mr r3,r4
+	blr
+END (BP_SYM (__longjmp))
diff -urN libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/fpu/__longjmp.S libc23/sysdeps/powerpc/powerpc32/fpu/__longjmp.S
--- libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/fpu/__longjmp.S	2003-02-17 14:46:03.000000000 -0600
+++ libc23/sysdeps/powerpc/powerpc32/fpu/__longjmp.S	2004-01-29 13:12:25.000000000 -0600
@@ -1,5 +1,5 @@
-/* longjmp for PowerPC.
-   Copyright (C) 1995, 1996, 1997, 1999, 2000 Free Software Foundation, Inc.
+/* AltiVec/VMX (new) version of __longjmp for PowerPC.
+   Copyright (C)  1995, 1996, 1997, 1999, 2000, 2004 Free Software Foundation, Inc.
    This file is part of the GNU C Library.
 
    The GNU C Library is free software; you can redistribute it and/or
@@ -17,57 +17,18 @@
    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
    02111-1307 USA.  */
 
-#include <sysdep.h>
-#define _ASM
-#define _SETJMP_H
-#include <bits/setjmp.h>
-#include <bp-sym.h>
-#include <bp-asm.h>
-
-ENTRY (BP_SYM (__longjmp))
-	CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
-
-	lwz r1,(JB_GPR1*4)(r3)
-	lwz r0,(JB_LR*4)(r3)
-	lwz r14,((JB_GPRS+0)*4)(r3)
-	lfd fp14,((JB_FPRS+0*2)*4)(r3)
-	lwz r15,((JB_GPRS+1)*4)(r3)
-	lfd fp15,((JB_FPRS+1*2)*4)(r3)
-	lwz r16,((JB_GPRS+2)*4)(r3)
-	lfd fp16,((JB_FPRS+2*2)*4)(r3)
-	lwz r17,((JB_GPRS+3)*4)(r3)
-	lfd fp17,((JB_FPRS+3*2)*4)(r3)
-	lwz r18,((JB_GPRS+4)*4)(r3)
-	lfd fp18,((JB_FPRS+4*2)*4)(r3)
-	lwz r19,((JB_GPRS+5)*4)(r3)
-	lfd fp19,((JB_FPRS+5*2)*4)(r3)
-	lwz r20,((JB_GPRS+6)*4)(r3)
-	lfd fp20,((JB_FPRS+6*2)*4)(r3)
-	mtlr r0
-	lwz r21,((JB_GPRS+7)*4)(r3)
-	lfd fp21,((JB_FPRS+7*2)*4)(r3)
-	lwz r22,((JB_GPRS+8)*4)(r3)
-	lfd fp22,((JB_FPRS+8*2)*4)(r3)
-	lwz r0,(JB_CR*4)(r3)
-	lwz r23,((JB_GPRS+9)*4)(r3)
-	lfd fp23,((JB_FPRS+9*2)*4)(r3)
-	lwz r24,((JB_GPRS+10)*4)(r3)
-	lfd fp24,((JB_FPRS+10*2)*4)(r3)
-	lwz r25,((JB_GPRS+11)*4)(r3)
-	lfd fp25,((JB_FPRS+11*2)*4)(r3)
-	mtcrf 0xFF,r0
-	lwz r26,((JB_GPRS+12)*4)(r3)
-	lfd fp26,((JB_FPRS+12*2)*4)(r3)
-	lwz r27,((JB_GPRS+13)*4)(r3)
-	lfd fp27,((JB_FPRS+13*2)*4)(r3)
-	lwz r28,((JB_GPRS+14)*4)(r3)
-	lfd fp28,((JB_FPRS+14*2)*4)(r3)
-	lwz r29,((JB_GPRS+15)*4)(r3)
-	lfd fp29,((JB_FPRS+15*2)*4)(r3)
-	lwz r30,((JB_GPRS+16)*4)(r3)
-	lfd fp30,((JB_FPRS+16*2)*4)(r3)
-	lwz r31,((JB_GPRS+17)*4)(r3)
-	lfd fp31,((JB_FPRS+17*2)*4)(r3)
-	mr r3,r4
-	blr
-END (BP_SYM (__longjmp))
+#include <libc-symbols.h>
+#include <rtld-global-offsets.h>
+#include <shlib-compat.h>
+
+default_symbol_version (__vmx__longjmp,__longjmp,GLIBC_2.3.4);
+#define __longjmp  __vmx__longjmp
+#include "__longjmp-common.S"
+
+#if defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4)
+#define __NO_VMX__
+symbol_version (__novmx__longjmp,__longjmp,GLIBC_2.0);
+#undef __longjmp
+#define __longjmp  __novmx__longjmp
+#include "__longjmp-common.S"
+#endif
diff -urN libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/fpu/setjmp-common.S libc23/sysdeps/powerpc/powerpc32/fpu/setjmp-common.S
--- libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/fpu/setjmp-common.S	Wed Dec 31 17:00:00 1969
+++ libc23/sysdeps/powerpc/powerpc32/fpu/setjmp-common.S	Fri Jan 30 14:17:34 2004
@@ -0,0 +1,170 @@
+/* setjmp for PowerPC.
+   Copyright (C) 1995-99, 2000, 2003, 2004 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+   AltiVec/VMX support contributed by Denis Joseph Barrow (dj@de.ibm.com).
+	
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+#define _ASM
+#define _SETJMP_H
+#ifdef __NO_VMX__
+#include <novmxsetjmp.h>
+#else
+#include <bits/setjmp.h>
+#endif
+#include <bp-sym.h>
+#include <bp-asm.h>
+	
+	
+ENTRY (BP_SYM (__sigsetjmp))
+	CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
+
+	stw  r1,(JB_GPR1*4)(3)
+	mflr r0
+	stw  r14,((JB_GPRS+0)*4)(3)
+	stfd fp14,((JB_FPRS+0*2)*4)(3)
+	stw  r0,(JB_LR*4)(3)
+	stw  r15,((JB_GPRS+1)*4)(3)
+	stfd fp15,((JB_FPRS+1*2)*4)(3)
+	mfcr r0
+	stw  r16,((JB_GPRS+2)*4)(3)
+	stfd fp16,((JB_FPRS+2*2)*4)(3)
+	stw  r0,(JB_CR*4)(3)
+	stw  r17,((JB_GPRS+3)*4)(3)
+	stfd fp17,((JB_FPRS+3*2)*4)(3)
+	stw  r18,((JB_GPRS+4)*4)(3)
+	stfd fp18,((JB_FPRS+4*2)*4)(3)
+	stw  r19,((JB_GPRS+5)*4)(3)
+	stfd fp19,((JB_FPRS+5*2)*4)(3)
+	stw  r20,((JB_GPRS+6)*4)(3)
+	stfd fp20,((JB_FPRS+6*2)*4)(3)
+	stw  r21,((JB_GPRS+7)*4)(3)
+	stfd fp21,((JB_FPRS+7*2)*4)(3)
+	stw  r22,((JB_GPRS+8)*4)(3)
+	stfd fp22,((JB_FPRS+8*2)*4)(3)
+	stw  r23,((JB_GPRS+9)*4)(3)
+	stfd fp23,((JB_FPRS+9*2)*4)(3)
+	stw  r24,((JB_GPRS+10)*4)(3)
+	stfd fp24,((JB_FPRS+10*2)*4)(3)
+	stw  r25,((JB_GPRS+11)*4)(3)
+	stfd fp25,((JB_FPRS+11*2)*4)(3)
+	stw  r26,((JB_GPRS+12)*4)(3)
+	stfd fp26,((JB_FPRS+12*2)*4)(3)
+	stw  r27,((JB_GPRS+13)*4)(3)
+	stfd fp27,((JB_FPRS+13*2)*4)(3)
+	stw  r28,((JB_GPRS+14)*4)(3)
+	stfd fp28,((JB_FPRS+14*2)*4)(3)
+	stw  r29,((JB_GPRS+15)*4)(3)
+	stfd fp29,((JB_FPRS+15*2)*4)(3)
+	stw  r30,((JB_GPRS+16)*4)(3)
+	stfd fp30,((JB_FPRS+16*2)*4)(3)
+	stw  r31,((JB_GPRS+17)*4)(3)
+	stfd fp31,((JB_FPRS+17*2)*4)(3)
+#ifndef __NO_VMX__
+#ifdef PIC
+	mflr    r6
+	bl      _GLOBAL_OFFSET_TABLE_@local-4
+	mflr    r5
+#ifdef SHARED
+	lwz     r5,_rtld_global@got(r5)
+	mtlr    r6
+	lwz     r5,RTLD_GLOBAL_DL_HWCAP_OFFSET(r5)	
+#else
+	lwz     r5,_rtld_global@got(r5)
+	mtlr    r6
+	lwz     r5,0(r5)
+#endif
+#else
+	lis	r5,_dl_hwcap@ha
+	lwz     r5,_dl_hwcap@l(r5)
+#endif
+	andis.	r5,r5,(PPC_FEATURE_HAS_ALTIVEC >> 16)
+	beq	no_vmx
+	la	r5,((JB_VRS)*4)(3)
+	andi.	r6,r5,0xf
+	mfspr	r0,VRSAVE
+	stw	r0,((JB_VRSAVE)*4)(3)
+	addi	r6,r5,16	
+	beq+	aligned_save_vmx	
+	lvsr	v0,0,r5
+	vspltisb v1,-1         /* set v1 to all 1's */
+	vspltisb v2,0          /* set v2 to all 0's */ 
+	vperm   v3,v2,v1,v0   /* v3 contains shift mask with num all 1 bytes on left = misalignment  */
+	
+
+	/* Special case for v20 we need to preserve what is in save area below v20 before obliterating it */	
+	lvx     v5,0,r5
+	vperm   v20,v20,v20,v0
+	vsel    v5,v5,v20,v3
+	vsel    v20,v20,v2,v3
+	stvx    v5,0,r5
+	
+#define save_2vmx_partial(savevr,prev_savevr,hivr,shiftvr,maskvr,savegpr,addgpr) \
+	addi    addgpr,addgpr,32; \
+	vperm   savevr,savevr,savevr,shiftvr; \
+	vsel    hivr,prev_savevr,savevr,maskvr; \
+	stvx    hivr,0,savegpr;
+
+	save_2vmx_partial(v21,v20,v5,v0,v3,r6,r5)
+	save_2vmx_partial(v22,v21,v5,v0,v3,r5,r6)
+	save_2vmx_partial(v23,v22,v5,v0,v3,r6,r5)	
+	save_2vmx_partial(v24,v23,v5,v0,v3,r5,r6)
+	save_2vmx_partial(v25,v24,v5,v0,v3,r6,r5)
+	save_2vmx_partial(v26,v25,v5,v0,v3,r5,r6)
+	save_2vmx_partial(v27,v26,v5,v0,v3,r6,r5)
+	save_2vmx_partial(v28,v27,v5,v0,v3,r5,r6)	
+	save_2vmx_partial(v29,v28,v5,v0,v3,r6,r5)
+	save_2vmx_partial(v30,v29,v5,v0,v3,r5,r6)
+	
+	/* Special case for r31 we need to preserve what is in save area above v31 before obliterating it */
+	addi    r5,r5,32
+	vperm   v31,v31,v31,v0
+	lvx     v4,0,r5
+	vsel    v5,v30,v31,v3
+	stvx    v5,0,r6
+	vsel    v4,v31,v4,v3
+	stvx    v4,0,r5	
+	b	no_vmx
+		
+aligned_save_vmx:
+	stvx	20,0,r5
+	addi	r5,r5,32
+	stvx	21,0,r6
+	addi	r6,r6,32
+	stvx	22,0,r5
+	addi	r5,r5,32
+	stvx	23,0,r6
+	addi	r6,r6,32
+	stvx	24,0,r5
+	addi	r5,r5,32
+	stvx	25,0,r6
+	addi	r6,r6,32
+	stvx	26,0,r5
+	addi	r5,r5,32
+	stvx	27,0,r6
+	addi	r6,r6,32
+	stvx	28,0,r5
+	addi	r5,r5,32
+	stvx	29,0,r6
+	addi	r6,r6,32
+	stvx	30,0,r5
+	stvx	31,0,r6
+no_vmx:		  
+#endif
+	b JUMPTARGET (BP_SYM (__sigjmp_save))
+END (BP_SYM (__sigsetjmp))
+
diff -urN libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/fpu/setjmp.S libc23/sysdeps/powerpc/powerpc32/fpu/setjmp.S
--- libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/fpu/setjmp.S	2003-02-17 14:46:03.000000000 -0600
+++ libc23/sysdeps/powerpc/powerpc32/fpu/setjmp.S	2004-02-04 14:24:18.000000000 -0600
@@ -1,5 +1,5 @@
-/* setjmp for PowerPC.
-   Copyright (C) 1995, 1996, 1997, 1999, 2000 Free Software Foundation, Inc.
+/* non alitivec (old) version of setjmp for PowerPC.
+   Copyright (C)  1995, 1996, 1997, 1999, 2000, 2003 Free Software Foundation, Inc.
    This file is part of the GNU C Library.
 
    The GNU C Library is free software; you can redistribute it and/or
@@ -17,56 +17,22 @@
    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
    02111-1307 USA.  */
 
-#include <sysdep.h>
-#define _ASM
-#define _SETJMP_H
-#include <bits/setjmp.h>
-#include <bp-sym.h>
-#include <bp-asm.h>
-
-ENTRY (BP_SYM (__sigsetjmp))
-	CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
-
-	stw  r1,(JB_GPR1*4)(3)
-	mflr r0
-	stw  r14,((JB_GPRS+0)*4)(3)
-	stfd fp14,((JB_FPRS+0*2)*4)(3)
-	stw  r0,(JB_LR*4)(3)
-	stw  r15,((JB_GPRS+1)*4)(3)
-	stfd fp15,((JB_FPRS+1*2)*4)(3)
-	mfcr r0
-	stw  r16,((JB_GPRS+2)*4)(3)
-	stfd fp16,((JB_FPRS+2*2)*4)(3)
-	stw  r0,(JB_CR*4)(3)
-	stw  r17,((JB_GPRS+3)*4)(3)
-	stfd fp17,((JB_FPRS+3*2)*4)(3)
-	stw  r18,((JB_GPRS+4)*4)(3)
-	stfd fp18,((JB_FPRS+4*2)*4)(3)
-	stw  r19,((JB_GPRS+5)*4)(3)
-	stfd fp19,((JB_FPRS+5*2)*4)(3)
-	stw  r20,((JB_GPRS+6)*4)(3)
-	stfd fp20,((JB_FPRS+6*2)*4)(3)
-	stw  r21,((JB_GPRS+7)*4)(3)
-	stfd fp21,((JB_FPRS+7*2)*4)(3)
-	stw  r22,((JB_GPRS+8)*4)(3)
-	stfd fp22,((JB_FPRS+8*2)*4)(3)
-	stw  r23,((JB_GPRS+9)*4)(3)
-	stfd fp23,((JB_FPRS+9*2)*4)(3)
-	stw  r24,((JB_GPRS+10)*4)(3)
-	stfd fp24,((JB_FPRS+10*2)*4)(3)
-	stw  r25,((JB_GPRS+11)*4)(3)
-	stfd fp25,((JB_FPRS+11*2)*4)(3)
-	stw  r26,((JB_GPRS+12)*4)(3)
-	stfd fp26,((JB_FPRS+12*2)*4)(3)
-	stw  r27,((JB_GPRS+13)*4)(3)
-	stfd fp27,((JB_FPRS+13*2)*4)(3)
-	stw  r28,((JB_GPRS+14)*4)(3)
-	stfd fp28,((JB_FPRS+14*2)*4)(3)
-	stw  r29,((JB_GPRS+15)*4)(3)
-	stfd fp29,((JB_FPRS+15*2)*4)(3)
-	stw  r30,((JB_GPRS+16)*4)(3)
-	stfd fp30,((JB_FPRS+16*2)*4)(3)
-	stw  r31,((JB_GPRS+17)*4)(3)
-	stfd fp31,((JB_FPRS+17*2)*4)(3)
-	b JUMPTARGET (BP_SYM (__sigjmp_save))
-END (BP_SYM (__sigsetjmp))
+#include <libc-symbols.h>
+#include <rtld-global-offsets.h>
+#include <shlib-compat.h>
+
+default_symbol_version (__vmx__sigsetjmp,__sigsetjmp,GLIBC_2.3.4)
+#define __sigsetjmp __vmx__sigsetjmp 
+#define __sigjmp_save __vmx__sigjmp_save
+#include "setjmp-common.S"
+
+#if defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4)
+#define __NO_VMX__
+#undef __sigsetjmp
+#undef __sigjmp_save
+symbol_version (__novmx__sigsetjmp,__sigsetjmp,GLIBC_2.0)
+#define __sigsetjmp __novmx__sigsetjmp 
+#define __sigjmp_save __novmx__sigjmp_save
+#include "setjmp-common.S"
+#endif
+
diff -urN libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/setjmp-common.S libc23/sysdeps/powerpc/powerpc32/setjmp-common.S
--- libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/setjmp-common.S	Wed Dec 31 17:00:00 1969
+++ libc23/sysdeps/powerpc/powerpc32/setjmp-common.S	Fri Jan 30 14:31:42 2004
@@ -0,0 +1,59 @@
+/* setjmp for PowerPC.
+   Copyright (C) 1995, 1996, 1997, 1999, 2000, 2001, 2003 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+#define _ASM
+#define _SETJMP_H
+#ifdef __NO_VMX__
+#include <novmxsetjmp.h>
+#else
+#include <bits/setjmp.h>
+#endif
+#include <bp-sym.h>
+#include <bp-asm.h>
+	
+	
+ENTRY (BP_SYM (__sigsetjmp))
+	CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
+
+	stw  r1,(JB_GPR1*4)(3)
+	mflr r0
+	stw  r14,((JB_GPRS+0)*4)(3)
+	stw  r0,(JB_LR*4)(3)
+	stw  r15,((JB_GPRS+1)*4)(3)
+	mfcr r0
+	stw  r16,((JB_GPRS+2)*4)(3)
+	stw  r0,(JB_CR*4)(3)
+	stw  r17,((JB_GPRS+3)*4)(3)
+	stw  r18,((JB_GPRS+4)*4)(3)
+	stw  r19,((JB_GPRS+5)*4)(3)
+	stw  r20,((JB_GPRS+6)*4)(3)
+	stw  r21,((JB_GPRS+7)*4)(3)
+	stw  r22,((JB_GPRS+8)*4)(3)
+	stw  r23,((JB_GPRS+9)*4)(3)
+	stw  r24,((JB_GPRS+10)*4)(3)
+	stw  r25,((JB_GPRS+11)*4)(3)
+	stw  r26,((JB_GPRS+12)*4)(3)
+	stw  r27,((JB_GPRS+13)*4)(3)
+	stw  r28,((JB_GPRS+14)*4)(3)
+	stw  r29,((JB_GPRS+15)*4)(3)
+	stw  r30,((JB_GPRS+16)*4)(3)
+	stw  r31,((JB_GPRS+17)*4)(3)
+	b JUMPTARGET (BP_SYM (__sigjmp_save))
+END (BP_SYM (__sigsetjmp))
diff -urN libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/setjmp.S libc23/sysdeps/powerpc/powerpc32/setjmp.S
--- libc23-cvstip-20040129/sysdeps/powerpc/powerpc32/setjmp.S	2003-02-17 14:46:03.000000000 -0600
+++ libc23/sysdeps/powerpc/powerpc32/setjmp.S	2004-02-04 14:24:01.000000000 -0600
@@ -1,5 +1,5 @@
-/* setjmp for PowerPC.
-   Copyright (C) 1995, 1996, 1997, 1999, 2000, 2001 Free Software Foundation, Inc.
+/* non alitivec (old) version of setjmp for PowerPC.
+   Copyright (C) 1995, 1996, 1997, 1999, 2000, 2001, 2004 Free Software Foundation, Inc.
    This file is part of the GNU C Library.
 
    The GNU C Library is free software; you can redistribute it and/or
@@ -17,38 +17,19 @@
    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
    02111-1307 USA.  */
 
-#include <sysdep.h>
-#define _ASM
-#define _SETJMP_H
-#include <bits/setjmp.h>
-#include <bp-sym.h>
-#include <bp-asm.h>
-
-ENTRY (BP_SYM (__sigsetjmp))
-	CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
-
-	stw  r1,(JB_GPR1*4)(3)
-	mflr r0
-	stw  r14,((JB_GPRS+0)*4)(3)
-	stw  r0,(JB_LR*4)(3)
-	stw  r15,((JB_GPRS+1)*4)(3)
-	mfcr r0
-	stw  r16,((JB_GPRS+2)*4)(3)
-	stw  r0,(JB_CR*4)(3)
-	stw  r17,((JB_GPRS+3)*4)(3)
-	stw  r18,((JB_GPRS+4)*4)(3)
-	stw  r19,((JB_GPRS+5)*4)(3)
-	stw  r20,((JB_GPRS+6)*4)(3)
-	stw  r21,((JB_GPRS+7)*4)(3)
-	stw  r22,((JB_GPRS+8)*4)(3)
-	stw  r23,((JB_GPRS+9)*4)(3)
-	stw  r24,((JB_GPRS+10)*4)(3)
-	stw  r25,((JB_GPRS+11)*4)(3)
-	stw  r26,((JB_GPRS+12)*4)(3)
-	stw  r27,((JB_GPRS+13)*4)(3)
-	stw  r28,((JB_GPRS+14)*4)(3)
-	stw  r29,((JB_GPRS+15)*4)(3)
-	stw  r30,((JB_GPRS+16)*4)(3)
-	stw  r31,((JB_GPRS+17)*4)(3)
-	b JUMPTARGET (BP_SYM (__sigjmp_save))
-END (BP_SYM (__sigsetjmp))
+#include <shlib-compat.h>
+#include <libc-symbols.h>
+default_symbol_version (__vmx__sigsetjmp,__sigsetjmp,GLIBC_2.3.4)
+#define __sigsetjmp __vmx__sigsetjmp 
+#define __sigjmp_save __vmx__sigjmp_save
+#include "setjmp-common.S"
+
+#if defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_0, GLIBC_2_3_4)
+#define __NO_VMX__
+#undef __sigsetjmp
+#undef __sigjmp_save
+symbol_version (__novmx__sigsetjmp,__sigsetjmp,GLIBC_2.0)
+#define __sigsetjmp __novmx__sigsetjmp 
+#define __sigjmp_save __novmx__sigjmp_save
+#include "setjmp-common.S"
+#endif

Index Nav: [Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav: [Date Prev] [Date Next] [Thread Prev] [Thread Next]