This is the mail archive of the docbook-apps@lists.oasis-open.org mailing list .


Index Nav: [Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav: [Date Prev] [Date Next] [Thread Prev] [Thread Next]

Re: Slides customization layer: special Header?


/ Jochen Hein <jochen@jochen.org> was heard to say:
| I'm requested to have a header similar to the following in my slides:

Something like this should work. This fixes the foils, you'll have to
do something similar in section-top-nav.

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform";
                version="1.0">

<xsl:import href="../xsl/slides.xsl"/>

<xsl:template name="foil-top-nav">
  <xsl:param name="prev-target" select="''"/>
  <xsl:param name="next-target" select="''"/>

  <xsl:variable name="section" select="ancestor::section"/>

  <xsl:variable name="nextfoil">
    <xsl:apply-templates select="(following::foil
                                 |following::section)[1]"
                         mode="filename"/>
  </xsl:variable>

  <xsl:variable name="prevfoil">
    <xsl:choose>
      <xsl:when test="preceding-sibling::foil">
        <xsl:apply-templates select="preceding-sibling::foil[1]"
                             mode="filename"/>
      </xsl:when>
      <xsl:when test="parent::section">
        <xsl:apply-templates select="parent::section[1]"
                             mode="filename"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$titlefoil.html"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:variable>

  <div class="navhead">
    <table BORDER="1" WIDTH="100%" BGCOLOR="#66FFFF" NOSAVE="NOSAVE" >
      <tr>
        <td>
          <table BORDER="1" COLS="1" WIDTH="100%" HEIGHT="30" BGCOLOR="#66FFFF" NOSAVE="NOSAVE">
            <tr>
              <td>
                <table BORDER="1" COLS="3" WIDTH="100%" BGCOLOR="#33CCFF" NOSAVE="NOSAVE" >
                  <tr>
                    <td>
                      <xsl:choose>
                        <xsl:when test="$prevfoil != ''">
                          <a href="{$prevfoil}">
                            <xsl:if test="$prev-target != ''">
                              <xsl:attribute name="target">
                                <xsl:value-of select="$prev-target"/>
                              </xsl:attribute>
                            </xsl:if>
                            <xsl:choose>
                              <xsl:when test="preceding-sibling::foil">
                                <xsl:value-of select="preceding-sibling::foil[1]/title"/>
                              </xsl:when>
                              <xsl:when test="parent::section">
                                <xsl:value-of select="parent::section[1]/title"/>
                              </xsl:when>
                              <xsl:otherwise>
                                <xsl:value-of select="/slides/slidesinfo/title"/>
                              </xsl:otherwise>
                            </xsl:choose>
                          </a>
                        </xsl:when>
                        <xsl:otherwise>&#160;</xsl:otherwise>
                      </xsl:choose>
                    </td>
                    <td><xsl:value-of select="title"/></td>
                    <td>
                      <xsl:choose>
                        <xsl:when test="$nextfoil != ''">
                          <a href="{$nextfoil}">
                            <xsl:if test="$next-target != ''">
                              <xsl:attribute name="target">
                                <xsl:value-of select="$next-target"/>
                              </xsl:attribute>
                            </xsl:if>
                            <xsl:value-of select="(following::foil
                                                  |following::section)[1]/title"/>
                          </a>
                        </xsl:when>
                        <xsl:otherwise>&#160;</xsl:otherwise>
                      </xsl:choose>
                    </td>
                  </tr>
                </table>
              </td>
            </tr>
            <tr>
              <td>
                <b>
                  <font size="+1">
                    <xsl:value-of select="title"/>
                  </font>
                </b>
              </td>
            </tr>
          </table>
        </td>
        <td>
          <img SRC="logo.gif" ALT="Logo" NOSAVE="NOSAVE"
               height="32" width="77"/>
        </td>
      </tr>
    </table>
  </div>
</xsl:template>

</xsl:stylesheet>

                                        Be seeing you,
                                          norm

-- 
Norman Walsh <ndw@nwalsh.com>      | What is familiar is what we are
http://www.oasis-open.org/docbook/ | used to; and what we are used to
Chair, DocBook Technical Committee | is most difficult to 'Know'--that
                                   | is, to see as a problem; that is,
                                   | to see as strange, as distant, as
                                   | 'outside us'.--Nietzsche


Index Nav: [Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav: [Date Prev] [Date Next] [Thread Prev] [Thread Next]